Ejemplos Set Analysis en Estados Alternos

Nota: La funcionalidad Estados Alternos sólo está en Qlikview 11
Para estos ejemplos debe crearse el Estado_A y el Estado_B  en:

Configuración\Propiedades del Documento\General\Estados Alternos\Añadir.

Luego se agregan los Cuadros de Listas, y en propiedades de estos Cuadros de Listas se va a General\Estado Alterno y se eligen los estados

1. Suma las ventas de las selecciones realizadas en el Estado_A

sum( {Estado_A }   Venta)

2. Suma las ventas de las selecciones realizadas en el Estado_A, para el Año 2011 

sum( {Estado_A <Año={2011}>}   Venta)

3. Suma las ventas de las selecciones realizadas en el Estado_A, para  el máximo Año seleccionado

sum( {Estado_A <Año={$(=max(Año))}>}   Venta)

4. Suma las ventas de las selecciones realizadas en el Estado_A, para el año 2011 y para Sucursal Norte

sum( {Estado_A   < Año={2011}, Sucursal={'Norte'} > } Venta)

5. Suma las ventas de las selecciones realizadas en el Estado_A considerando la selección realizada en Año

sum( {Estado_A <Año=$::Año>} Venta)

6. Suma las ventas de las selecciones realizadas en el Estado_A considerando la selección realizada en Año y Sucursal.
sum( {Estado_A <Año=$::Año,Sucursal=$::Sucursal>} Venta)

7. Suma las ventas considerando la  Sucursal seleccionada en el Estado_A
sum( {<Sucursal=Estado_A::Sucursal>} Venta)

8. Suma las ventas considerando la Sucursal seleccionada en el Estado_A y el Año seleccionado en el Estado_B
sum( {<Sucursal=Estado_A::Sucursal,Año=Estado_B::Año>} Venta)

NOTA: Las siguientes expresiones de Set Analysis obtienen el mismo resultado: Sucursales no seleccionadas.
1.{<Sucursal=-Sucursal>}
2.{<Sucursal=-$::Sucursal>} 

3.{<Sucursal=E({$})>}

Para otros ejemplos de set analysis ver: 
1. http://qlikviewapuntes.blogspot.com.ar/2013/12/ejemplos-set-analysis-de-grupo.html
2. http://qlikviewapuntes.blogspot.com.ar/2013/12/ejemplos-de-set-analysis-dinamico.html
3. http://qlikviewapuntes.blogspot.com.ar/2013/12/ejemplos-de-set-analysis.html

Referencias
http://community.qlik.com/blogs/qlikviewdesignblog/2015/02/16/set-analysis
http://www.learnqlickview.com/alternate-states-in-qlikview/
http://qlikboard.com/2012/12/04/set-analysis-alternate-states-quick-tip/
http://www.learnallbi.com/qlikview-alternate-states-part-2/
http://www.qlikcommunity.com/docs/DOC-4386

Desvincular una Tabla con Set Analysis

En algunas ocasiones se quiere un gráfico que no esté vinculado a las selecciones de todos los campos de una tabla Calendario (u otra tabla).

Puede hacerse un Set Analysis desvinculando cada campo, pero esto podría ser muy extenso y tendría que modificarse en caso que se agregue otro campo en la tabla Calendario.

Una técnica para desvincular todos los campos de una tabla podría ser la siguiente:

1. Cargar datos de ejemplo
Ventas:
    LOAD * INLINE [
    Fecha, Sucursal, Venta
    2/01/2011, Este, 485
    10/08/2009, Oeste, 106
    3/08/2009, Sur, 708
    7/11/2011, Norte, 351
    9/04/2010, Oeste, 308];

Calendario:
     LOAD Fecha,
     day(Fecha)         as Dia,
     Week(Fecha)        as Semana,
     Month(Fecha)       as Mes,
     QuarterName(Fecha) as Trimestre,
     Year(Fecha)        as Año
Resident Ventas; 

Esto creará la siguiente relación:

2. Crear variable  en Configuración\Panel de Variables > Añadir. 

Se asigna nombre de variable: Desvincular_Calendario

En Definición se escribe:
[$(=Concat({1<$Table={'Calendario'}>}distinct $Field,']=,[')&']=')

3. Se crea un grafico de Tabla Simple con la siguiente Dimensión y Expresión:

Dimensión = Sucursal

Expresión = Sum( {<$(Desvincular_Calendario)>} Venta)

Este nuevo grafico de tabla simple no se verá afectada por las selecciones realizadas en los campos de la tabla Calendario.

Referencias:
 http://blog.inspari.dk/2013/07/04/a-better-alternative-to-long-set-analysis/

Ejemplos Set Analysis de Grupo

1. Dentro de la selección realizada, cuenta únicamente las IdLlamada que pertenecen al marcador IdLLamadasSospechosas NOTA: Antes debe crearse este marcador en Marcadores\Añadir Marcador.

Count(  {$*IdLLamadasSospechosas}  IdLlamada )

2. Cuenta IdAgente  que pertenecen a dos grupos, tanto a marcador IdAgenteMayoresVentas como también a marcador IdAgenteMenoresLLamadas. NOTA: Antes debe crearse este marcador en Marcadores\Añadir Marcador.

Count( {IdAgenteMayoresVentas*IdAgenteMenoresLLamadas} IdAgente)

3. Cuenta los IdAgente  que pertenecen a uno de los dos marcadores (IdAgenteMayoresVentas ó IdAgenteMayoresLLamadas), pero no a ambos.

Count( {IdAgenteMayoresVentas/IdAgenteMayoresLLamadas} IdAgente)

4. Suma Ventas de EEUU  y  EUROPA. Ignora selección en  Pais y Continente. (funciona como OR).

            Sum( { <Pais={'EEUU'}> + <Continente={'EUROPA'}> } Ventas)

5. Dentro de la selección, suma Ventas de países que no pertenecen a EUROPA ni son EEUU. Ignora selección en  Pais yContinente.

             Sum( {$-<Pais={'EEUU'}>-<Continente={'EUROPA'}> } Ventas)

6. Calcula en qué porciento las  Ventas de EEUU+EUROPA sobrepasa la suma de las Ventas del resto de países que no son EEUU o pertenecen a EUROPA.

              Sum( { <Pais={'EEUU'}> + <Continente={'EUROPA'}> } Ventas)

/Sum( {$-<Pais={'EEUU'}> - <Continente={'EUROPA'}> } Ventas)

7. Suma las ventas de los países seleccionados más las ventas de EEUU, aún si este no está seleccionado
             Sum( { <Pais=Pais+{'EEUU'}>} Ventas)

8. Promedio de DeudaActual de clientes que alguna vez tuvieron DiasAtraso mayor a 360 días.

Avg( {< Cliente = P({1<DiasAtraso={">360"}>}) >} DeudaActual)

9. Promedio de DeudaActual de clientes que NUNCA  tuvieron DiasAtraso mayor a 360 días.

Avg({< Cliente = E({1<DiasAtraso={">360"}>})  >} DeudaActual)

10. Dentro de la selección realizada, cuenta clientes que alguna vez tuvieron AñoCompra=2013.

Count( {< Cliente= P({1<AñoCompra={2013}>}) >} DISTINCT Cliente)

11. Clientes que compraron en 2012 y 2013:

Dentro de la selección realizada, cuenta únicamente clientes que tuvieron AñoCompra en 2012 y 2013.

Count({<Cliente=

P({1<AñoCompra={2012}>})

*P({1<AñoCompra={2013}>})

>}DISTINCT Cliente)

12. Cliente con 2 años antigüedad:

Cuenta clientes que compraron tanto el último AñoCompra seleccionado como también en el AñoCompra anterior al seleccionado.

Count(  { <Cliente=

 P({1<AñoCompra={$(=Max(AñoCompra)-1)}>})

*P({1<AñoCompra={$(=Max(AñoCompra))}>})

> } DISTINCT Cliente)

13. Clientes inactivos con respecto al año anterior:

Dentro de la selección realizada, cuenta los clientes que no tuvieron AñoCompra igual al año seleccionado, pero sí tuvieronAñoCompra el año anterior al seleccionado.

Count({1< Cliente=

           E({<AñoCompra={$(=Max(AñoCompra))}>})

          *P({<AñoCompra={$(=Max(AñoCompra)-1)}>})

>} DISTINCT Cliente) 

14. Clientes nuevos en el año:

Cuenta los clientes que tuvieron su primer AñoCompra el año seleccionado.

Count({1< Cliente =
      E({1<AñoCompra={"<$(=Max(AñoCompra))"}>})
     *P({1<AñoCompra={"$(=Max(AñoCompra))"}>})
>} DISTINCT Cliente)

15. Clientes nuevos en el primer trimestre del 2012:

Cuenta los clientes que tuvieron su primer FechaCompra entre Enero y Marzo del 2012.

=Count({<Cliente=
      P({1<FechaCompra={">=01/01/2012<=31/03/2012"}>})
     *E({1<FechaCompra={"<01/01/2012"}>})

>} DISTINCT Cliente) 

16. Clientes con 90 días inactivos:

Cuenta los clientes que NO han tenido FechaCompra durante 90 días o mas a partir de fecha seleccionada.
=Count({<FechaCompra, Cliente=    

      E({1<FechaCompra={">=$(=date(max(FechaCompra)-90))<=$(=date(max(FechaCompra)))"}>})
     *P({1<FechaCompra={"<=$(=date(max(FechaCompra)-90))"}>})
>} DISTINCT Cliente) 

NOTA: Las siguientes expresiones de Set Analysis obtienen el mismo resultado: Sucursales no seleccionadas.
1.{<Sucursal=-Sucursal>}
2.{<Sucursal=-$::Sucursal>} 

3.{<Sucursal=E({$})>}

Para otros ejemplos de set analysis ver: 

1. http://qlikviewapuntes.blogspot.com.ar/2014/01/ejemplos-set-analysis-en-estados.html

2. http://qlikviewapuntes.blogspot.com.ar/2013/12/ejemplos-de-set-analysis-dinamico.html

3. http://qlikviewapuntes.blogspot.com.ar/2013/12/ejemplos-de-set-analysis.html

Referencia:

http://www.qlikcommunity.com/docs/DOC-4386

http://community.qlik.com/blogs/qlikviewdesignblog/2015/02/16/set-analysis